View source for Left 4 Dead 2/Scripting/Script Functions/AddThinkToEnt

Turns a function of an entity's script into a think function, which then the function automatically calls itself in an interval set by number returns if they exist, otherwise the <code>sv_script_think_interval</code> cvar is used (0.1 seconds by default). There can only be one think function for each entity at a time, so you can't chain think functions.

To remove think functions, call this function with <code>null</code> as an argument under the ''funcname'' parameter. See this sub-section of the [[Entity_Scripts#Thinker_Functions|Entity Scripts]] page to know more about think functions.

__TOC__

== Parameters ==
'''void AddThinkToEnt(CBaseEntity ''entity'',string ''funcname'')'''
{| class="standard-table" style="width: 50%;"
! Type
! Name
! Description
|-
| CBaseEntity
| entity
| Target entity to be applied a think function.
|-
| string
| funcname
| Given the string, find the function of the ''exact'' same name (no brackets allowed!). Pass<code>null</code>to remove it.
|}

== Code Samples ==
=== Fastest Rethink Rate ===
[[File:L4D2ScriptFunctions_AddThinkToEnt-FastestRethinkRate.png|thumb|right|super|300px]]
When ran, an [[info_target]] will be spawned with a think function that automatically uses the fastest possible rethink rate (that's capped). The think function uses [[Left 4 Dead 2/Scripting/Script Functions/ClientPrint|ClientPrint()]] and fills the chatbox about how long the game has been running. When it has sent the messages 30 times, the entity will then delete itself, thus halting the think function.

Since {{l4d2}} runs on [[Source_Multiplayer_Networking#Servers_that_Support_Tickrate|30 ticks]] by default, think functions can never run faster than 0.03333... seconds. See this sub-section of the [[Entity_Scripts#Thinker_Functions|Entity Scripts]] page to know more about think functions.
{{Expand|
<syntaxhighlight lang=js>
local timethinker = SpawnEntityFromTable("info_target", { targetname = "timethinker" } )
if( timethinker.ValidateScriptScope() )
{
	const MAX_PRINT_TIMES = 30
	timethinker.GetScriptScope()["PrintCount"] <- 0
	timethinker.GetScriptScope()["Think"] <- function()
	{
		if( timethinker.GetScriptScope()["PrintCount"] < MAX_PRINT_TIMES )
		{
			ClientPrint(null, DirectorScript.HUD_PRINTTALK, "\x04"+"Current Time: "+"\x05"+Time().tostring())
			timethinker.GetScriptScope()["PrintCount"]++
			return 0.01	// can't actually rethink this fast; quick way to ensure it rethinks at the rethink rate cap
		}
		else
		{
			ClientPrint(null, DirectorScript.HUD_PRINTTALK, "\x03"+"We printed enough times already.")
			self.Kill()
		}
	}
	AddThinkToEnt(timethinker, "Think")
}
</syntaxhighlight>}}

=== Survivor Health Decay ===
[[File:L4D2ScriptFunctions_AddThinkToEnt-SurvivorHealthDecay.png|thumb|right|super|300px|Look at Rochelle, Ellis and Coach's health.]]
This script applies a slow think function onto all players, which will then slowly decay their normal health, and turn it into temporary health. It also implements a buffer system, a period where health decay attempts will not be allowed.
{{Expand|
<syntaxhighlight lang=js>
const HEALTH_DECAY_TIME = 2
const HEALTH_DECAY_BUFFERCOUNT = 5
local player = null
while( player = Entities.FindByClassname(player,"player") )
{
	// Team 4 is the L4D1 Passing Survivors; they're invincible!
	if( player.IsSurvivor() && NetProps.GetPropInt(player, "m_iTeamNum") != 4 )
	{
		if( player.ValidateScriptScope() )
		{
			local player_entityscript = player.GetScriptScope()
			player_entityscript["HealthDecayBufferCount"] <- HEALTH_DECAY_BUFFERCOUNT
			player_entityscript["HealthDecay"] <- function()
			{
				if( player_entityscript["HealthDecayBufferCount"] < 0 )
				{
					// Bots lose the think function when they die, anyways
					if( !self.IsIncapacitated() && !self.IsDead() && !self.IsHangingFromLedge() )
					{
						if( self.GetHealth() > 1 )
						{
							self.SetHealth( self.GetHealth()-1 )
							self.SetHealthBuffer( self.GetHealthBuffer()+1 )
							printl(GetCharacterDisplayName(self)+" is decaying health!")
						}
						else
							printl(GetCharacterDisplayName(self)+" isn't able to decay health anymore.")
					}
					else
						printl(GetCharacterDisplayName(self)+" is currently not allowed to decay health.")
				}
				else
				{
					player_entityscript["HealthDecayBufferCount"] -= 1
					printl(GetCharacterDisplayName(self)+" is in health decay buffer")
				}
				return HEALTH_DECAY_TIME
			}
		}
	}
	AddThinkToEnt(player, "HealthDecay")
	printl("Applied health decaying to "+player)
}
</syntaxhighlight>
}}
[[Category:Left 4 Dead 2]]
[[Category:Scripting]]